Array declarations

[RayYates]

Is there any functional difference between these two array declarations? If NOT is there any benifit to using one over the other?

<MvASSIGNARRAY NAME = "l.all_settings:orders" VALUE = "{ l.temp_records }">
    <MvDIMENSION INDEX = "{ l.pos }">
    <MvMEMBER NAME = "shipments">
</MvASSIGNARRAY>

<MvASSIGN NAME="l.all_settings:orders"
  INDEX="{ l.pos }" 
  MEMBER="shipments"  
  VALUE="{ l.temp_records }">

[mvmarkus]

Re: Array declarations

Hi Ray,

I have never seen any functional (or performance) differences other than ease of reading/writing the code. When designing complex arrays of structures, I usually prefer the first way of writing it, even though it's a pain to write.

Best,

Markus

[aGorilla]

Re: Array declarations

Personally, I hate breaking the tags out. I long ago adopted a style that just builds the name inline.

<MvASSIGN NAME="{'l.all_settings:orders[' $ l.pos $ ']:shipments'}" VALUE="{ l.temp_records }">

It may seem a bit cryptic at first, but I find it a lot easier to read, and a lot easier to rearrange my structure when needed.

I did some benchmarking years ago, and there were some differences, but I don't recall which method was the fastest. Whatever the differences were, they didn't change my coding practices.

[Kent Multer]

Re: Array declarations

I also use the inline style of assignment in some cases. It's shorter than using a lot of tag and attribute names. Also, you can use it to reach deep into a structure, e.g. to change the value of something with a name like

l.items[l.i]:options[l.j]:price

.

[RayYates]

Re: Array declarations

Thanks for the response gents. It's as I suspected.

I too use the MvASSIGN syntax, often in combination with MvREFERENCE

For a complex structure like this

l.products[l.prod_index]:attributes[l.attr_index]:options[l.opt_index]

You could use this

<MvREFERENCE NAME = "l.option" VARIABLE = "{ 
  'l.products[' $ l.prod_index $ 
  ']:attributes[' $ l.attr_index $ 
  ']:options[' $ l.opt_index $ ']' }">

<MvASSIGN NAME="l.option:code" VALUE="{ g.code }">
<MvASSIGN NAME="l.option:prompt" VALUE="{ g.prompt}"> etc.

[mvmarkus]

Re: Array declarations

Thanks for the response gents. It's as I suspected.

I too use the MvASSIGN syntax, often in combination with MvREFERENCE

For a complex structure like this

l.products[l.prod_index]:attributes[l.attr_index]:options[l.opt_index]

You could use this

<MvREFERENCE NAME = "l.option" VARIABLE = "{ 
  'l.products[' $ l.prod_index $ 
  ']:attributes[' $ l.attr_index $ 
  ']:options[' $ l.opt_index $ ']' }">

<MvASSIGN NAME="l.option:code" VALUE="{ g.code }">
<MvASSIGN NAME="l.option:prompt" VALUE="{ g.prompt}"> etc.

Hi Ray,

That's exactly what I try to do as often as possible. When dealing with large arrays, this can really bring a significant performance advantage en lieu of assigning the structure to another variable (just to make it easier to read).

[Kent Multer]

Re: Array declarations

Yeah, MvREFERENCE is very handy.

Another good tip to enhance performance is to use VAR on function parameters, even when you don't need it, if the parameter will have a lot of data in it. Using VAR means that Empresa won't copy the whole thing into a local variable every time it calls the function.

[RayYates]

Re: Array declarations

That's a very good point.

[RayYates]

Re: Array declarations

I must have missed this release note:

What exactly does this tag do? <MvREFERENCEARRAY>

<MvWHILE EXPR = "{ l.attribute_pos LE l.attribute_count }">
        <MvREFERENCEARRAY NAME = "l.attribute" VARIABLE = "l.attributes">
            <MvDIMENSION INDEX = "{ l.attribute_pos }">
        </MvREFERENCEARRAY>

[mvmarkus]

Re: Array declarations

I must have missed this release note:

What exactly does this tag do? <MvREFERENCEARRAY>

<MvWHILE EXPR = "{ l.attribute_pos LE l.attribute_count }">
        <MvREFERENCEARRAY NAME = "l.attribute" VARIABLE = "l.attributes">
            <MvDIMENSION INDEX = "{ l.attribute_pos }">
        </MvREFERENCEARRAY>

Wow! I have never seen this before (in the "docs" ). Where did you find it?

I guess it's the array/structure version of MvREFERENCE. Very good to know.

MvREFERENCE basically creates a pointer to a variable. The advantage is that very little memory is needed and the original var is updated when you update the referenced variable (unlike a regular MvASSIGN).

MvREFERENCEARRAY makes the syntax easier, since sometimes assigning variables inline to a referenced array becomes quite tedious and error-prone (at least for me...).

[RayYates]

Re: Array declarations

I found it referenced first in Miva Merchant * Empresa 5.07 - Release Notes.txt

Then found more by searching the LSK source files.

I have all the release notes except those from 5.03 through 5.06. (Please send them if you have them to ray.yates AT pcinet.com)

I recently (just last week) had to parse an flat inventory file to create this structure for an XML data feed.

l.all_settings:products[x]:code
l.all_settings:products[x]:name... etc.
l.all_settings:products[x]:colors[y]:code
l.all_settings:products[x]:colors[y]:name
l.all_settings:products[x]:colors[y]:sizes[z]:code
l.all_settings:products[x]:colors[y]:sizes[z]:name
l.all_settings:products[x]:colors[y]:sizes[z]:quantity

Inside the While loop I used MvREFERENCE to create a reference to each sub structure.

<MvASSIGN NAME="l.products" INDEX="{ l.data_ndx }" MEMBER="code"  VALUE="{ l.this_code }">
... more assignments ...

Later...

<MvREFERENCE NAME = "l.colors" VARIABLE = "{ 'l.products[' $ l.product_ndx $ ']:colors' }">
<MvASSIGN NAME="l.colors" INDEX="{ l.color_ndx }" MEMBER="code"  VALUE="{ l.this_color }">
... more assignments ...

<MvREFERENCE NAME = "l.sizes" VARIABLE = "{ 'l.colors[' $ l.color_ndx $ ']:sizes' }">
<MvASSIGN NAME="l.sizes" INDEX="{ l.size_ndx }" MEMBER="code"  VALUE="{ l.this_size }">

I'm thinking I could have used something like this, if I had know about it, but I don't think I have it exactly right.

<MvREFERENCEARRAY NAME = "l.colors" VARIABLE = "l.products">
   <MvDIMENSION INDEX = "{ l.product_ndx }">
   <MvMEMBER NAME= "colors">
</MvREFERENCEARRAY>

<MvASSIGN NAME="l.colors" INDEX="{ l.color_ndx }" MEMBER="code"  VALUE="{ l.this_color }">

[mvmarkus]

Re: Array declarations

[code]<MvREFERENCEARRAY NAME = "l.colors" VARIABLE = "l.products">
<MvDIMENSION INDEX = "{ l.product_ndx }">
<MvMEMBER NAME= "colors">
</MvREFERENCEARRAY>

Hi Ray,

I just tried the MvREFERENCEARRAY and it works indeed. Great find!

Interesting little twist with MvREFERENCE:
By mistake I MvREFERENCEARRAY (l.colors) to another reference with the same name: And guess what. Empresa caused a timeout!

<MvASSIGN NAME = "l.this" VALUE = "LALALALALA" >

<MvREFERENCEARRAY NAME = "l.colors" VARIABLE = "l.this">
   <MvDIMENSION INDEX = "1">
   <MvMEMBER NAME= "colors">
</MvREFERENCEARRAY>

<BR>COLORS: <MvEVAL EXPR = "{ l.colors[1]:colors }" >

<MvREFERENCEARRAY NAME = "l.colors" VARIABLE = "l.colors">
   <MvDIMENSION INDEX = "2">
   <MvMEMBER NAME= "colors2">
</MvREFERENCEARRAY>


<BR>COLORS: <MvEVAL EXPR = "{ miva_array_serialize(l.colors) }" >

-> Empresa timeout.

This here works just fine:

<MvASSIGN NAME = "l.this" VALUE = "LALALALALA" >

<MvREFERENCEARRAY NAME = "l.colors" VARIABLE = "l.this">
   <MvDIMENSION INDEX = "1">
   <MvMEMBER NAME= "colors">
</MvREFERENCEARRAY>

<BR>COLORS: <MvEVAL EXPR = "{ l.colors[1]:colors }" >

<MvREFERENCEARRAY NAME = "l.colors2" VARIABLE = "l.colors">
   <MvDIMENSION INDEX = "2">
   <MvMEMBER NAME= "colors2">
</MvREFERENCEARRAY>


<BR>COLORS: <MvEVAL EXPR = "{ miva_array_serialize(l.colors2) }" >

RESULT:

COLORS: LALALALALA
COLORS: [2]:COLORS2[1]:COLORS=LALALALALA



Markus



Markus

[RayYates]

Re: Array declarations

You should post the bug. http://bugzilla.mivamerchant.com/

[Kent Multer]

Re: Array declarations

FYI, MvREFERENCEARRAY, like MvASSIGNARRAY, is not needed. I often use statements like these when operating on items in the basket:

<MvREFERENCE NAME="l.item" VARIABLE="{ 'l.items[' $ l.i $ ']' }">
<MvREFERENCE name="l.option" VARIABLE="{ 'l.items[' $ l.i $ ']:options[' $ l.o $ ']' }">

I haven't had any timeout problems.

[burch]

Re: Array declarations

Most likely, what happened is that you made a circular variable reference (child pointed to something in its parent), which caused miva_array_serialize to enter an infinite loop.

This isn't necessarily a bug in MvREFERENCE/MvREFERENCEARRAY, because there are cases where you may want to create such a circular reference. We do this ourselves in the upgrade code.

It's also not really a bug in miva_array_serialize(), because no matter what it does it could never generate a serialized string that reconstructs into the original variable. About the best thing it could do is detect a loop and terminate with an error or truncated output.