Run Fulfillment from Admin Only

[Bruce - PhosphorMedia]

Is there any way to have a Fulfillment Module run ONLY if selected in the Manage Orders Fulfillment Modules function?

[ids]

Re: Run Fulfillment from Admin Only

My first thought, yes if there is a variable value generated to bounce off. Like, if g.admin_screen EQ "Manage Orders" then run-it. So, the module itself needs an If-Else condition.

Otherwise, I think the checkbox list when clicking the Man Ord Fulfill tab is the only control.

Side Note: I have found when running this tab, I don't have control over which Order Fulfillment Template Emails to run. IOW, unless I am not understanding something, if I check template emails, All the active email templates will run.

Scott

[Kent Multer]

Re: Run Fulfillment from Admin Only

If one of my clients wanted this, I would write a small "phantom" fulfillment module that passes all function calls to the real module, but only when it's running in admin, not from the shopping pages. Then I'd deactivate the real module, so that it would never run on its own. That's off the top of my head, but I think it'll work.

[eMediaSales]

Re: Run Fulfillment from Admin Only

I do this in softgoods:

<MvASSIGN NAME="l.in_admin" VALUE="{ CheckFor_InAdmin() }">

    <MvIF EXPR="{l.in_admin}">
        <MvCOMMENT> ** ALWAYS RUN HERE ** </MvCOMMENT>
    <MvELSE>
        <MvCOMMENT> ** SOMETIMES RUN HERE ** </MvCOMMENT>
    </MvIF>

...

<MvFUNCTION NAME="CheckFor_InAdmin" PARAMETERS="" STANDARDOUTPUTLEVEL="">
<MvCOMMENT>
****
file name in Wombat's Manage Orders is json.mvc, hence the check for that file
****
</MvCOMMENT>

    <MvASSIGN NAME="l.string" VALUE="{tolower(s.documenturl)}">
    <MvASSIGN NAME="l.string" VALUE="{glosub(l.string,'http://','')}">
    <MvASSIGN NAME="l.string" VALUE="{glosub(l.string,'https://','')}">
    <MvASSIGN NAME="l.count" VALUE="1">
    <MvASSIGN NAME="l.this_portion" VALUE="{gettoken(l.string,'/',l.count)}">
    <MvWHILE EXPR="{l.this_portion}">
        <MvIF EXPR="{'.mvc' CIN l.this_portion}">
            <MvIF EXPR="{(substring(l.this_portion,1,9) EQ 'admin.mvc') OR ((substring(l.this_portion,1,8) EQ 'json.mvc'))}">
                <MvFUNCRETURN VALUE="1">
            <MvELSE>
                <MvFUNCRETURN VALUE="0">
            </MvIF>
        </MvIF>

        <MvASSIGN NAME="l.count" VALUE="{l.count + 1}">
        <MvASSIGN NAME="l.this_portion" VALUE="{gettoken(l.string,'/',l.count)}">
    </MvWHILE>
    <MvFUNCRETURN VALUE="0">
</MvFUNCTION>

Probably could be better but seems to get the job done.

James

[Kent Multer]

Re: Run Fulfillment from Admin Only

Bruce, is this a fulfillment module that you're writing? Sorry, I assumed you were talking about controlling someone else's module, where you don't have access to the source code. If you can modify the source, I think you can just make it check for "admin.mvc" in the value of s.documenturl.